### 4.4.3 ideal operations

`+`
  addition (concatenation of the generators and simplification)

`*`
  multiplication (with ideal, poly, vector, module; simplification in case of multiplication with ideal)

`^`
  exponentiation (by a non-negative integer)

ideal_expression `[` intvec_expression `]`
  are polynomial generators of the ideal, index 1 gives the first generator.

Note: For simplification of an ideal, see also simplify.

Example:

      ring r=0,(x,y,z),dp;
      ideal I = 0,x,0,1;
      I;
    ==> I[1]=0
    ==> I[2]=x
    ==> I[3]=0
    ==> I[4]=1
      I + 0;    // simplification
    ==> _[1]=1
      ideal J = I,0,x,x-z;;
      J;
    ==> J[1]=0
    ==> J[2]=x
    ==> J[3]=0
    ==> J[4]=1
    ==> J[5]=0
    ==> J[6]=x
    ==> J[7]=x-z
      I * J;   //  multiplication with simplification
    ==> _[1]=1
      I*x;
    ==> _[1]=0
    ==> _[2]=x2
    ==> _[3]=0
    ==> _[4]=x
      vector V = [x,y,z];
      print(V*I);
    ==> 0,x2,0,x,
    ==> 0,xy,0,y,
    ==> 0,xz,0,z
      ideal m = maxideal(1);
      m^2;
    ==> _[1]=x2
    ==> _[2]=xy
    ==> _[3]=xz
    ==> _[4]=y2
    ==> _[5]=yz
    ==> _[6]=z2
      ideal II = I[2..4];
      II;
    ==> II[1]=x
    ==> II[2]=0
    ==> II[3]=1

User manual for Singular version 4-0-3, 2016, generated by texi2html.