### 5.1.63 jet

`Syntax:`
  `jet (` poly_expression`,` int_expression `)`
  `jet (` vector_expression`,` int_expression `)`
  `jet (` ideal_expression`,` int_expression `)`
  `jet (` module_expression`,` int_expression `)`
  `jet (` poly_expression`,` int_expression`,` intvec_expression `)`
  `jet (` vector_expression`,` int_expression`,` intvec_expression `)`
  `jet (` ideal_expression`,` int_expression`,` intvec_expression `)`
  `jet (` module_expression`,` int_expression`,` intvec_expression `)`
  `jet (` poly_expression`,` poly_expression`,` int_expression `)`
  `jet (` vector_expression`,` poly_expression`,` int_expression `)`
  `jet (` ideal_expression`,` matrix_expression`,` int_expression `)`
  `jet (` module_expression`,` matrix_expression`,` int_expression `)`
`Type:`
  the same as the type of the first argument
`Purpose:`
  deletes from the first argument all terms of degree bigger than the second argument.
  If a third argument `w` of type intvec is given, the degree is replaced by the weighted degree defined by `w`.
  If a second argument `u` of type poly or matrix is given, the first argument `p` is replaced by `p/u`.
`Example:`

        ring r=32003,(x,y,z),(c,dp);
        jet(1+x+x2+x3+x4,3);
      ==> x3+x2+x+1
        poly f=1+x+x2+xz+y2+x3+y3+x2y2+z4;
        jet(f,3);
      ==> x3+y3+x2+y2+xz+x+1
        intvec iv=2,1,1;
        jet(f,3,iv);
      ==> y3+y2+xz+x+1
        // the part of f with (total) degree >3:
        f-jet(f,3);
      ==> x2y2+z4
        // the homogeneous part of f of degree 2:
        jet(f,2)-jet(f,1);
      ==> x2+y2+xz
        // the part of maximal degree:
        jet(f,deg(f))-jet(f,deg(f)-1);
      ==> x2y2+z4
        // the absolute term of f:
        jet(f,0);
      ==> 1
        // now for other types:
        ideal i=f,x,f*f;
        jet(i,2);
      ==> _[1]=x2+y2+xz+x+1
      ==> _[2]=x
      ==> _[3]=3x2+2y2+2xz+2x+1
        vector v=[f,1,x];
        jet(v,1);
      ==> [x+1,1,x]
        jet(v,0);
      ==> [1,1]
        v=[f,1,0];
        module m=v,v,[1,x2,z3,0,1];
        jet(m,2);
      ==> _[1]=[x2+y2+xz+x+1,1]
      ==> _[2]=[x2+y2+xz+x+1,1]
      ==> _[3]=[1,x2,0,0,1]
        ring rs=0,x,ds;
        // 1/(1+x) till degree 5
        jet(1,1+x,5);
      ==> 1-x+x2-x3+x4-x5

See deg; ideal; int; intvec; module; poly; vector.

User manual for Singular version 4-0-3, 2016, generated by texi2html.